/////////////////////////////////////////////////////////////////////
// DRAW IN WINDOW
/////////////////////////////////////////////////////////////////////

#xcommand DRAW TEXT IN WINDOW <windowname> ;
      AT <nRow>, <nCol> ;
      VALUE <cString> ;
      [ FONT <cFont> ] ;
      [ SIZE <nSize> ] ;
      [ BACKCOLOR <aBkRGB> ] ;
      [ FONTCOLOR <aRGB> ] ;
      [ <lBold: BOLD> ] ;
      [ <lItalic: ITALIC> ] ;
      [ <lUnderline: UNDERLINE> ] ;
      [ <lStrikeout: STRIKEOUT> ] ;
      [ <transparent: TRANSPARENT> ] ;
   => ;
      DrawTextOut( <(windowname)>, <nRow>, <nCol>, <cString>, <aRGB>, ;
            <aBkRGB>, <cFont>, <nSize>, <.lBold.>, <.lItalic.>, ;
            <.lUnderline.>, <.lStrikeout.>, <.transparent.> )

#xcommand DRAW LINE IN WINDOW <windowname> AT <frow>, <fcol> ;
      TO <trow>,<tcol> ;
      [ PENCOLOR <penrgb> ] ;
      [ PENWIDTH <pnwidth> ] ;
   => ;
      DrawLine( <(windowname)>, <frow>, <fcol>, <trow>, <tcol>, ;
            [<penrgb>], <pnwidth> )

#xcommand DRAW RECTANGLE IN WINDOW <windowname> AT <frow>, <fcol> ;
      TO <trow>, <tcol> ;
      [ PENCOLOR <penrgb> ] ;
      [ PENWIDTH <pnwidth> ] ;
      [ FILLCOLOR <fillrgb> ] ;
   => ;
      DrawRect( <(windowname)>, <frow>, <fcol>, <trow>, <tcol>, [<penrgb>], ;
            <pnwidth>, [<fillrgb>] )

#xcommand DRAW ROUNDRECTANGLE IN WINDOW <windowname> AT <frow>, <fcol> ;
      TO <trow>, <tcol> ;
      ROUNDWIDTH <width> ;
      ROUNDHEIGHT <height>;
      [ PENCOLOR <penrgb> ] ;
      [ PENWIDTH <pnwidth> ] ;
      [ FILLCOLOR <fillrgb> ] ;
   => ;
      DrawRoundRect( <(windowname)>, <frow>, <fcol>, <trow>, <tcol>, <width>, ;
            <height>, [<penrgb>], <pnwidth>, [<fillrgb>] )

#xcommand DRAW ELLIPSE IN WINDOW <windowname> AT <frow>, <fcol> ;
      TO <trow>, <tcol> ;
      [ PENCOLOR <penrgb> ] ;
      [ PENWIDTH <pnwidth> ] ;
      [ FILLCOLOR <fillrgb> ] ;
   => ;
      DrawEllipse( <(windowname)>, <frow>, <fcol>, <trow>, <tcol>, [<penrgb>], ;
            <pnwidth>, [<fillrgb>] )

#xcommand DRAW ARC IN WINDOW <windowname> AT <frow>, <fcol> ;
      TO <trow>, <tcol> ;
      FROM RADIAL <rrow>, <rcol> ;
      TO RADIAL <rrow1>, <rcol1> ;
      [ PENCOLOR <penrgb>] ;
      [ PENWIDTH <pnwidth>] ;
   => ;
   DrawArc( <(windowname)>, <frow>, <fcol>, <trow>, <tcol>, <rrow>, <rcol>, ;
         <rrow1>, <rcol1>, [<penrgb>], <pnwidth> )

#xcommand DRAW PIE IN WINDOW <windowname> AT <frow>, <fcol> ;
      TO <trow>, <tcol> ;
      FROM RADIAL <rrow>, <rcol> ;
      TO RADIAL <rrow1>, <rcol1> ;
      [ PENCOLOR <penrgb> ] ;
      [ PENWIDTH <pnwidth> ] ;
      [ FILLCOLOR <fillrgb> ] ;
   => ;
   DrawPie( <(windowname)>, <frow>, <fcol>, <trow>, <tcol>, <rrow>, <rcol>, ;
         <rrow1>, <rcol1>, [<penrgb>], <pnwidth>, [<fillrgb>] )

/*
 * POINTS must be specified using this syntax:
 *    { {row1, col1}, {row2, col2}, {row3, col3}, ... }
 */
#xcommand DRAW POLYGON IN WINDOW <windowname> ;
      POINTS <pointsarr> ;
      [ PENCOLOR <penrgb> ] ;
      [ PENWIDTH <penwidth> ] ;
      [ FILLCOLOR <fillrgb> ] ;
   => ;
      DrawPolygon( <(windowname)>, [<pointsarr>], [<penrgb>], ;
            <penwidth>, [<fillrgb>] )

#xcommand DRAW POLYBEZIER IN WINDOW <windowname> ;
      POINTS <pointsarr> ;
      [ PENCOLOR <penrgb> ] ;
      [ PENWIDTH <penwidth> ] ;
   =>;
      DrawPolyBezier( <(windowname)>, [<pointsarr>], [<penrgb>], <penwidth> )

#xcommand ERASE WINDOW <windowname> ;
   => ;
      EraseWindow( <(windowname)> )

#xcommand DEFAULT <uVar1> := <uVal1> [, <uVarN> := <uValN> ] ;
   => ;
      <uVar1> := IIF( <uVar1> == NIL, <uVal1>, <uVar1> ) ;;
      [ <uVarN> := IIF( <uVarN> == NIL, <uValN>, <uVarN> ) ; ]

#translate RGB( <nRed>, <nGreen>, <nBlue> ) ;
   => ;
      ( <nRed> + ( <nGreen> * 256 ) + ( <nBlue> * 65536 ) )

#xcommand DRAW GRAPH IN WINDOW <windowname> ;
      AT <nT>, <nL> ;
      TO <nB>, <nR> ;
      TITLE <cTitle> ;
      TYPE PIE ;
      SERIES <aSer> ;
      DEPTH <nD> ;
      SERIENAMES <aName> ;
      COLORS <aColor> ;
      [ <l3D: 3DVIEW> ] ;
      [ <lxVal: SHOWXVALUES> ] ;
      [ <lSLeg: SHOWLEGENDS> ] ;
      [ <lNoBorder: NOBORDER> ] ;
   => ;
      DrawPieGraph( <(windowname)>, <nT>, <nL>, <nB>, <nR>, <aSer>, <aName>, ;
            <aColor>, <cTitle>, <nD>, <.l3D.>, <.lxVal.>, <.lSLeg.>, ;
            <.lNoBorder.> )

/*
 * <nType> valid values are:
 *    "BARS" or 1
 *    "LINES" or 2
 *    "POINTS" or 3
 */
#xcommand DRAW GRAPH ;
      IN WINDOW <windowname> ;
      AT <nT>, <nL> ;
      [ TO <nB>, <nR> ] ;
      [ TITLE <cTitle> ] ;
      TYPE <nType> ;
      SERIES <aSer> ;
      YVALUES <aYVal> ;
      DEPTH <nD> ;
      [ BARWIDTH <nW> ] ;
      HVALUES <nRange> ;
      SERIENAMES <aName> ;
      COLORS <aColor> ;
      [ <l3D: 3DVIEW> ] ;
      [ <lGrid: SHOWGRID> ] ;
      [ <lxVal: SHOWXVALUES> ] ;
      [ <lyVal: SHOWYVALUES> ] ;
      [ <lSLeg: SHOWLEGENDS> ] ;
      [ LEGENDSWIDTH <nLegendWindth> ] ;
      [ <lNoborder: NOBORDER> ] ;
   => ;
      GraphShow( <(windowname)>, <nT>, <nL>, <nB>, <nR>, NIL, NIL, <aSer>, ;
            <cTitle>, <aYVal>, <nD>, <nW>, NIL, <nRange>, <.l3D.>, <.lGrid.>, ;
            .F., .F., <.lxVal.>, <.lyVal.>, <.lSLeg.>, <aName>, <aColor>, ;
            <(nType)>, .F., NIL, <nLegendWindth>, <.lNoborder.> )

#xcommand DRAW PANEL IN WINDOW <windowname> ;
      AT <frow>, <fcol> ;
      TO <trow>, <tcol> ;
   => ;
      DrawWindowBoxRaised( <(windowname)>, <frow>, <fcol>, <trow>, <tcol> )

#xcommand DRAW BOX IN WINDOW <windowname> ;
      AT <frow>, <fcol> ;
      TO <trow>, <tcol> ;
   => ;
      DrawWindowBoxIn( <(windowname)>, <frow>, <fcol>, <trow>, <tcol> )