/////////////////////////////////////////////////////////////////////
// MINIPRINT @... COMMANDS
/////////////////////////////////////////////////////////////////////

#xcommand @ <Row>, <Col> PRINT [ DATA ] <cText> ;
      [ <lfont: FONT> <cFontName> ] ;
      [ <lsize: SIZE> <nFontSize> ] ;
      [ <bold: BOLD> ] ;
      [ <italic: ITALIC> ] ;
      [ <underline: UNDERLINE> ] ;
      [ <strikeout: STRIKEOUT> ] ;
      [ <lcolor: COLOR> <aColor> ] ;
      [ <lAngle: ANGLE> <nAngle> ] ;
      [ <lWidth: WIDTH> <nWidth> ] ;
   => ;
      _HMG_PRINTER_H_Print( _HMG_PRINTER_hDC, <Row>, <Col>, <cFontName>, ;
         <nFontSize>, <aColor>\[1\], <aColor>\[2\], <aColor>\[3\], <cText>, ;
         <.bold.>, <.italic.>, <.underline.>, <.strikeout.>, <.lcolor.>, ;
         <.lfont.>, <.lsize.>, <.lAngle.>, <nAngle>, <.lWidth.>, <nWidth> )

#xcommand @ <Row>, <Col> PRINT [ DATA ] <cText> ;
      TO <ToRow>, <ToCol> ;
      [ <lfont: FONT> <cFontName> ] ;
      [ <lsize: SIZE> <nFontSize> ] ;
      [ <bold: BOLD> ] ;
      [ <italic: ITALIC> ] ;
      [ <underline: UNDERLINE> ] ;
      [ <strikeout: STRIKEOUT> ] ;
      [ <lcolor: COLOR> <aColor> ] ;
      [ <lAngle: ANGLE> <nAngle> ] ;
      [ <lWidth: WIDTH> <nWidth> ] ;
   => ;
      _HMG_PRINTER_H_MultiLine_Print( _HMG_PRINTER_hDC, <Row>, <Col>, <ToRow>, ;
         <ToCol>, <cFontName>, <nFontSize>, <aColor>\[1\], <aColor>\[2\], ;
         <aColor>\[3\], <cText>, <.bold.>, <.italic.>, <.underline.>, ;
         <.strikeout.>, <.lcolor.>, <.lfont.>, <.lsize.>, <.lAngle.>, ;
         <nAngle>, <.lWidth.>, <nWidth> )

#xcommand @ <nRow>, <nCol> PRINT IMAGE <cImage> ;
      WIDTH <nWidth> ;
      HEIGHT <nheight> ;
      [ <stretch: STRETCH> ] ;
   => ;
      _HMG_PRINTER_H_Image( _HMG_PRINTER_hDC, <cImage>, <nRow>, <nCol>, ;
         <nheight>, <nWidth>, <.stretch.> )