/////////////////////////////////////////////////////////////////////
// STATUSBAR
/////////////////////////////////////////////////////////////////////

#xcommand DEFINE STATUSBAR ;
      [ <dummy1: OF, PARENT> <parent> ] ;
      [ OBJ <obj> ] ;
      [ <kbd: KEYBOARD> ] ;
      [ <date: DATE> ] ;
      [ <clock: CLOCK> ] ;
      [ FONT <fontname> ] ;
      [ SIZE <fontsize> ] ;
      [ <bold: BOLD> ] ;
      [ <top: TOP> ] ;
      [ <italic: ITALIC> ] ;
      [ <underline: UNDERLINE> ] ;
      [ <strikeout: STRIKEOUT> ] ;
      [ MESSAGE <msg> ] ;
      [ SUBCLASS <subclass> ] ;
      [ <noautoadjust: NOAUTOADJUST> ] ;
      [ WIDTH <nSize> ] ;
      [ ACTION <uAction> ] ;
      [ ICON <cBitmap> ] ;
      [ <styl: FLAT, RAISED> ] ;
      [ TOOLTIP <cToolTip> ] ;
      [ <align: LEFT, CENTER, RIGHT> ] ;
   => ;
      [ <obj> := ] _OOHG_SelectSubClass( TMessageBar(), [ <subclass>() ] ): ;
            Define( "StatusBar", <(parent)>, 0, 0, 0, 0, <msg>, <{uAction}>, ;
            <fontname>, <fontsize>, <cToolTip>, <.clock.>, <.date.>, <.kbd.>, ;
            NIL, NIL, <.bold.>, <.italic.>, <.underline.>, <.strikeout.>, ;
            <.top.>, <.noautoadjust.>, <nSize>, <cBitmap>, <(styl)>, <(align)> )

#xcommand END STATUSBAR ;
   => ;
      _EndMessageBar ()

#xcommand STATUSITEM [ <cMsg> ] ;
      [ WIDTH <nSize> ] ;
      [ ACTION <uAction> ] ;
      [ ICON <cBitmap> ] ;
      [ <styl: FLAT, RAISED> ] ;
      [ TOOLTIP <cToolTip> ] ;
      [ <align: LEFT, CENTER, RIGHT> ] ;
   => ;
      _SetStatusItem( <cMsg>, <nSize>, <{uAction}>, <cToolTip>, <cBitmap>, ;
            <(styl)>, <(align)> )

#xcommand DATE ;
      [ <w: WIDTH > <nSize> ] ;
      [ ACTION <uAction> ] ;
      [ TOOLTIP <cToolTip> ] ;
      [ <styl: FLAT, RAISED> ] ;
      [ <align: LEFT, CENTER, RIGHT> ] ;
   => ;
      _SetStatusItem( Dtoc( Date() ), ;
            IIF( <.w.>, <nSize>, ;
            IIF( "yyyy" $ Lower( Set( _SET_DATEFORMAT ) ), 95, 75 ) ), ;
            <{uAction}>, <cToolTip>, NIL, <(styl)>, <(align)> )

#xcommand CLOCK ;
      [ WIDTH <nSize> ] ;
      [ ACTION <uAction> ] ;
      [ TOOLTIP <cToolTip> ] ;
      [ <ampm: AMPM> ] ;
      [ ICON <cBitmap> ] ;
      [ <styl: FLAT, RAISED> ] ;
      [ <align: LEFT, CENTER, RIGHT> ] ;
   => ;
      _SetStatusClock( <nSize>, <cToolTip>, <{uAction}>, <.ampm.>, <cBitmap>, ;
            <(styl)>, <(align)> )

#xcommand KEYBOARD ;
      [ WIDTH <nSize> ] ;
      [ ACTION <uAction> ] ;
      [ TOOLTIP <cToolTip> ] ;
      [ ICON <cBitmap> ] ;
      [ <styl: FLAT, RAISED> ] ;
      [ <align: LEFT, CENTER, RIGHT> ] ;
   => ;
      _SetStatusKeybrd( <nSize>, <cToolTip>, <{uAction}>, <cBitmap>, ;
            <(styl)>, <(align)> )